BrightSign HD110 Owner's manual

1
Roku Object
Reference
Matches HD110, HD210, HD410, HD810, HD1010 Software Version: 3.1.46

2
Table of Contents
INTRODUCTION ............................................................................................................................. 4
ROKU OBJECT INTERFACES AND METHODS .......................................................................... 4
INHERITANCE ................................................................................................................................ 5
CLASSES........................................................................................................................................ 5
OBJECT AND CLASS NAME SYNTAX......................................................................................... 5
ZONES ............................................................................................................................................ 5
BRIGHTSIGN OBJECT LIBRARY ................................................................................................. 7
EVENT LOOPS ............................................................................................................................... 7
CLASSES....................................................................................................................................... 8
roList..................................................................................................................................................... 8
roMessagePort...................................................................................................................................... 9
roVideoMode ...................................................................................................................................... 10
roVideoPlayer..................................................................................................................................... 12
roAudioPlayer..................................................................................................................................... 14
roVideoEvent() and roAudioEvent() ................................................................................................... 18
roGpioControlPort ............................................................................................................................. 19
roGpioButton ...................................................................................................................................... 19
roQuadravoxSNS5 .............................................................................................................................. 20
roQuadravoxButton ............................................................................................................................ 20
roKeyboard ......................................................................................................................................... 21
roKeyboardPress ................................................................................................................................ 21
roIRRemote ......................................................................................................................................... 22
roIRRemotePress ................................................................................................................................ 22
roImagePlayer, roImageWidget.......................................................................................................... 23
roInt, roFloat, roString ....................................................................................................................... 25
roTouchScreen .................................................................................................................................... 27
roSerialPort ........................................................................................................................................ 31
roDeviceInfo ....................................................................................................................................... 32
roRegistry ()........................................................................................................................................ 33
roRegistrySection () ............................................................................................................................ 33
roSystemTime () .................................................................................................................................. 34
roDateTime () ..................................................................................................................................... 35
roTimer ()............................................................................................................................................ 36
roReadFile, roCreateFile, roReadWriteFile, roAppendFile ().......................................................... 38
roTextField ()...................................................................................................................................... 40
roAssociativeArray ().......................................................................................................................... 42
roRectangle () ..................................................................................................................................... 43
roTextWidget () ................................................................................................................................... 44
roResourceManager ()........................................................................................................................ 46
roClockWidget ()................................................................................................................................. 47
roUrlTransfer ().................................................................................................................................. 49
roUrlEvent ()....................................................................................................................................... 51
roRssParser, roRssArticle () ............................................................................................................... 54
roNetworkConfiguration () ................................................................................................................. 55
roStorageInfo () .................................................................................................................................. 56
roBrightPackage () ............................................................................................................................. 57

3
roDatagramSender, roDatagramReceiver () ...................................................................................... 59
roVideoInput() .................................................................................................................................... 60

4
Introduction
Roku Objects (RO) are the standardized way Roku software exposes functionality for our products’ public
SDKs. In other words, to publish a new API, Roku will create a new Roku Object. The first product to
use this method is the BrightSign.
Roku Objects have these key objectives:
•To be largely language independent.
•To be robust to software upgrades. A RO interface, once established, never changes its methods
or its binary linkage.
•To be compatible with compiled or interpreted languages. ROs are completely discoverable and
callable at run time or compile time.
•To support multiple abstract interfaces. This allows objects to be used in powerful ways as we’ll
see below.
As well as the core Roku Object architecture, this reference also defines event architecture and the required
interfaces to participate in this scheme. The event scheme is a fundamental piece of any multi-threaded
application. Its standardization is the first part in a sequence of RO based standards Roku will adopt across
our products, to maximize compatibility of third party plug-ins.
This document describes the Roku Object architecture as two main sections:
•how to use them (as a script writer)
•the initial objects defined for BrightSign
Roku Object Interfaces and Methods
Every Roku Object consists of one or more “Interfaces”. An RO Interface consists of one or more
Methods. For example, the roVideoPlayer has two interfaces: ifMediaTransport and ifSetMessagePort.
The Interface ifSetMessagePort has one Member: SetPort.
For example:
p = CreateObject("roMessagePort")
video= CreateObject("roVideoPlayer")
gpio = CreateObject("roGpioControlPort")
gpio.SetPort(p)
video.SetPort(p)
This syntax makes use of a short cut provided by the language: The interface name is optional, unless it is
needed to resolve name conflicts.
For example:
gpio.SetPort(p)
is the same as:
gpio.ifSetMessagePort.SetPort(p)
Note that the abstract Interface ifSetMessagePort is exposed and implemented by both the
roGpioControlPort and the roVideoPlayer objects. Once the method SetPort is called, these objects will
send their events to the supplied message port. This is discussed more in the Event section below.
Once an interface is defined and published, it is never changed. For example, imagine if Roku decided in a
future release that the ifSetMessagePort really needed another method, say “ClearMessagePort”. Instead of
changing the ifSetMessagePort interface, we would create a new interface ifSetMessagePort2. This

5
interface would contain only the new methods. The “old” method still exists in the original Interface.
Older applications will only use the original interface, but newer applications could use the original and the
new interface. This ensures full backwards compatibility with the installed base of Roku scripts and
applications with future versions of Roku products.
Roku Objects consist only of interfaces. Interfaces define only methods. There is no concept of a
“property” or variable at the Object or Interface level. These must be implemented as Set/Get methods in
an Interface.
Inheritance
There is no explicit support for Inheritance in the RO architecture. However, this section is a brief
discussion of how C++ concepts of inheritance map to ROs.
•Use of Virtual Base classes to abstract interfaces. For example, in C++ one might create a
virtual base class for a AsciiStream Object. Then create implementation class for an RS232Port,
TCP, or Keyboard. This type of functionality is accomplished with Roku Objects by defining an
Interface (for example ifAsciiStream), then ROs that expose this interface (e.g. the roTCP)
•Use of “Mix-in” classes to bring-in existing functionality. ROs don’t have an exact equivalent.
If the writer of an object wants to bring-in existing RO they can create them and hold a reference
to them internally. If the object creator wants to expose a created objects Interface(s), it must
expose the same interface (all interfaces are public), and then when an interface method is called,
the RO calls the appropriate Interface of a called object.
Classes
A Class Name is the name used to create a Roku Object. For example:
video= CreateObject("roVideoPlayer")
roVideoPlayer is the class name.
Object and Class Name Syntax
Class names:
•must start with an alphabetic character (a – z)
•may consist of alphabetic characters, numbers, or the symbol “_” (underscore)
•they are not case sensitive
•may be of any reasonable length
Zones
With the BrightSign Zones feature, you can divide the screen into rectangles and play different content in
each rectangle.
A zone can contain video and images, images, a clock, or text. There can be only one video zone per
screen. However, there can be multiple of other types of zones on the screen. A text zone can contain
simple text strings or can be configured to display an RSS feed in a ticker type display.
To enable zone functionality, the following global function must be called in the script:
EnableZoneSupport(enable As Boolean) As Void
When zones are enabled, the image layer is always on top of the video layer. When zones are not enabled,
the image layer is hidden whenever video is played, and the video layer is hidden whenever images are
played.

6
Example:
This script creates 5 zones. The first one contains a video player, the next two contain image players, the
fourth has a clock widget and the last is a text widget. The objects used in this example are explained in
subsequent sections of this document.
debug = true
v=CreateObject("roVideoMode")
v.SetMode("1920x1080x60i")
EnableZoneSupport(true)
r=CreateObject("roRectangle", 60, 60, 1386, 800)
v=CreateObject("roVideoPlayer")
v.SetRectangle(r)
v.SetLoopMode(1)
v.SetViewMode(2)
v.SetAudioOutput(2)
v.PlayFile("Amazon_1080.mpg")
i1=CreateObject("roImagePlayer")
i1.SetDefaultMode(3)
r=CreateObject("roRectangle", 100, 100, 285, 123)
i1.SetRectangle(r)
i1.DisplayFile("splash_master.png")
i2=CreateObject("roImagePlayer")
i2.SetDefaultMode(2)
r=CreateObject("roRectangle", 1520, 155, 300, 300)
i2.SetRectangle(r)
ok=i2.DisplayFile("museum_ad1.jpg")
if ok=0 then
i2.DisplayFile("museum_ad1.jpg")
endif
i3=CreateObject("roImagePlayer")
i3.SetDefaultMode(2)
r=CreateObject("roRectangle", 1520, 565, 300, 300)
i3.SetRectangle(r)
ok=i3.DisplayFile("museum_ad2.jpg")
if ok=0 then
i3.DisplayFile("museum_ad2.jpg")
endif
r=CreateObject("roRectangle", 1520, 50, 300, 100)
res=CreateObject("roResourceManager", "resources.txt")
c=CreateObject("roClockWidget",r, res, true)
c.Show()
r=CreateObject("roRectangle", 60, 900, 1800, 100)
t=CreateObject("roTextWidget", r, 3, 0, 5)
t.SetForegroundColor(&ha0a0a0)
t.PushString("The next Museum tour will be starting at 2:30pm in
the lobby.")
t.PushString("Visit the Museum Store today for 15% all
purchases.")
t.PushString("Become a museum member and today's visit is free.")

7
t.PushString("BrightSign solid-state media players power
interactive video exhibits with simplicity, reliability and
interactivity to high-impact digital signage. Learn more at
www.roku.com/brightsign.")
t.Show()
p=CreateObject("roMessagePort")
sw = CreateObject("roGpioControlPort")
sw.SetPort(p)
msg_loop:
msg=wait(0,p)
if type(msg)="roGpioButton" then
if debug AND msg=12 then 'Video Select
end
endif
else
print "Unknown event "; type(event)
endif
goto msg_loop
BrightSign Object Library
This section specifies each of the Roku Objects that are included with BrigthScript.
Event Loops
When creating anything more than a very simple script, an Event Loop will need to be created. An Event
Loop typically has this structure:
1. wait for the event
2. process the event
3. jump back to 1
Events are things like a button press, a timer that has triggered, a video that has finished playing back, etc.
By convention, Roku Object (RO) events work as follows.
•A RO of type “roMessagePort” is created. In BrightScript, by the user’s script.
•ROs that can send events are instructed to send their events to this message port. You could set up
multiple message ports, and have each event go to its own message port, but it is usually simpler
to just create one message port, and have the events all go to this one port. To instruct the RO to
send events to a specific port, use the ifSetMessagePort Interface.
•The script waits for an event. The actual function to do this is the ifMessagePort.WaitMessage(),
but if you are using BrightScript, the built-in statement WAIT makes this easy.
•If multiple event types are possible, your script should determine which event that the wait
received, then process it. The script then jumps back to the Wait.
An “Event” can be generated by any Roku Object. For example, the class “roGpioControlPort” sends
events of type “roGpioButton”. The “roGpioButton” has one interface: ifInt. ifInt allows access to an
integer. An event loop needs to be aware of the possible events it can get, and process them.

8
Example
print "BrightSign Button-LED Test Running"
p = CreateObject("roMessagePort")
tmr = CreateObject("roMessagePort")
gpio = CreateObject("roGpioControlPort")
gpio.SetPort(p)
event_loop:
msg=wait(0, p)
if type(msg)<>"roGpioButton" then event_loop
butn = msg.GetInt()
if butn > 5 then event_loop
gpio.SetOutputState(butn+17,1)
print "Button Pressed: ";butn
msg = wait (500, tmr)
gpio.SetOutputState(butn+17,0)
clear_events:
msg=p.GetMessage():if type(msg)<>"rotINT32" then clear_events
goto event_loop
Classes
For each class a brief description is given, a list of interfaces, and the member functions in the interfaces.
roList
A general purpose doubly link list. It can be used as a container for arbitrary length lists of Roku Objects.
Interfaces:
•ifList
Count() As Integer
IsEmpty() As Boolean
ResetIndex() As Boolean
AddTail(obj As Object) As Void
AddHead(obj As Object) As Void
FindIndex(name As String) As Boolean
RemoveIndex() As Object
GetIndex() As Object
RemoveTail() As Object
RemoveHead() As Object
GetTail() As Object
GetHead() As Object

9
roMessagePort
A message port is the place messages (events) are sent. See the “Event Loops” section for more details.
When using Roku BrightScript, you would not call these functions directly. Instead, use the “Wait”
BrightScript statement (see the BrightScript documentation).
Interfaces:
•ifMessagePort
GetMessage() As Object
WaitMessage(timeout As Integer) As Object
PostMessage(msg As Object) As Void

10
roVideoMode
This class allows you to set the output video resolution. The same video resolution is applied to all video
outputs on BrightSign. Video or images that are subsequently decoded and displayed will be scaled (using
the hardware scalar) to this output resolution if necessary.
Interfaces:
•ifVideoMode
SetMode(mode As String) As Boolean
•ifVideoMode
GetResX() As Integer
•ifVideoMode
GetResY() As Integer
•ifVideoMode
GetSafeX() As Integer
•ifVideoMode
GetSafeY() As Integer
•ifVideoMode
GetSafeWidth() As Integer
•ifVideoMode
GetSafeHeight() As Integer
•ifVideoMode
SetPowerSaveMode(power_save_enable As Boolean) As Boolean
•ifSetMessagePort
SetPort(obj As Object) As Void
Supported modes that can be passed to SetMode on the HD110, HD210, HD410, HD810 and HD1010 are:
•“auto”
•“640x480x60p”
•“800x600x75p”
•“1024x768x75p”
•“1360x768x60p”
•“720x576x50p”
•“720x480x60p”
•“1280x720x50p”
•“1280x720x59.94p”
•“1280x720x60p”
•“1920x1080x50i”
•“1920x1080x59.94i”
•“1920x1080x60i”
•“1920x1080x29.97p”
•“1920x1080x50p”
•“1920x1080x60p”